curlingthebrackets / flash / flash-emne / as3 /

package {
    // ::: A ::: // flAAsh clAAsses importeres
    import flash.display.MovieClip;
 
    public class ABC extends MovieClip {       
        // ::: B ::: // variaBBler og oBBjekter BBliver BBrugbare i kommende funktioner
 
        public function ABC() {
        // ::: C ::: // CConstruCCtor - Indledende handlinger
 
        }
        // ::: D ::: // DDiverse funktioner DDu laver DDem
 
    }
}

//A
	import flash.net.URLRequest;
	import flash.net.URLLoader;
//B
	var XMLLoader:URLLoader = new URLLoader();
//C/D i relevant sammenhæng
	XMLLoader.load(new URLRequest("adressen_paa_din_xml_fil.xml")); 
	XMLLoader.addEventListener(Event.COMPLETE, onLoadXML);
//D
	function onLoadXML(e:Event):void  {
		var xml:XML = new XML(e.target.data);//xml i en string
		var xmlList:XMLList = new XMLList(xml.children());//emne liste
		trace(xml); //Prøv også: trace(xmlList);
	}

//Paste fx. denne adresse ind i URLLoaderen's URLRequest: 
'http://curlingthebrackets.com/category/flash/feed/'
//og lav denne trace: 
trace(xmlList.item.title);

<?xml version="1.0" encoding="utf-8"?>
<images>
	<image full="images/image1.jpg" thumb="thumbnails/image1.jpg">Description of image 1.</image>
	<image full="images/image2.jpg" thumb="thumbnails/image2.jpg">Description of image 2.</image>
	<image full="images/image3.jpg" thumb="thumbnails/image3.jpg">Description of image 3.</image>
</images>

var gallery1:gallery=new gallery();
addChild(gallery1);

package {
	/// :::: A :::: /// Import af flash classes
	import flash.display.MovieClip;
	import flash.events.*;
	public class gallery extends MovieClip {		
		/// :::: B :::: /// Oprettelse af variabler og tilgængeliggørelse af objekt-navne
		public function gallery() {	
			/// :::: C :::: /// Indledende handlinger - "constructor"
		}
		/// :::: D :::: /// Tilknyttede funktioner	
	}
}

	/// :::: A :::: /// Import af flash classes
 
	/// :::: B :::: /// Oprettelse af variabler og tilgængeliggørelse af objekt-navne
 
	/// :::: C :::: /// Indledende handlinger - "constructor"
 
	/// :::: D :::: /// Tilknyttede funktioner

//Niveau A
	import flash.net.URLRequest;
	import flash.net.URLLoader;
//Niveau B
		public var xmlDoc:String="data/images.xml"; //Adressen på xml-filen
		public var xmlLoader:URLLoader=new URLLoader(); //Opret det relevante URLLoader-objekt
		public var xml:XML; //Navnet på xml-objektet
		public var xmlList:XMLList; //Navnet på den liste, hvori xml.elementerne kommer til at stå
//Niveau C
			// Load xml-filen med adressen
			xmlLoader.load(new URLRequest(xmlDoc));
			// Når xml-filen er færdig-loadet, udføres XMLCOMPLETE funktionen
			xmlLoader.addEventListener(Event.COMPLETE, XMLCOMPLETE);
//Niveau D
		public function XMLCOMPLETE(e:Event):void {
			// Påfyld flash's xml-beholder med xmlLoader-data!
			xml=XML(e.target.data);
			// Oplist elementerne fra xml-filens "rod" i rækkefølge
			xmlList=xml.children();
			// Udfør funktionen LOADTHUMBS
			LOADTHUMBS();
		}

//Niveau A
	// URLRequest skal kun tilføjes hvis den ikke er importeret på trin 1
	import flash.net.URLRequest;
	import flash.display.Loader;
//Niveau B
		public var thumbLoader:Loader;
//Niveau D
		public function LOADTHUMBS():void {
			var thumbUrl:String;
			// For hvert element i xml-filen dannes en "thumbLoader"
			for (var i:int=0; i<xmlList.length(); i++) {
				//værdien af hver "thumb" attribut overføres til thumbUrl
				thumbUrl=xmlList[i].attribute("thumb");
				thumbLoader=new Loader();
				thumbLoader.load(new URLRequest(thumbUrl));
				//thumbLoader bliver snedigt omdøbt til adressen på det fulde billede
				thumbLoader.name=xmlList[i].attribute("full");
				thumbLoader.x=20;
				// 130=thumb's bredde, 20= passende luft 
				thumbLoader.y=i*130+20;
				addChild(thumbLoader);
				// hver thumbLoader aktiveres til at kunne udføre SHOWFULL
				thumbLoader.addEventListener(MouseEvent.CLICK, SHOWFULL);
			}
		}

//Niveau A
	// URLRequest skal kun importeres hvis den ikke allerede er der
	import flash.net.URLRequest;
	// Loader er allerede importeret i trin 2, skal kun tilføjes hvis den mangler
	import flash.display.Loader;
//Niveau B
		public var fullLoader:Loader;
//Niveau D
		public function SHOWFULL(e:MouseEvent):void {
			// fjern det viste billede, hvis der er et i forvejen
			if (fullLoader) {
				removeChild(fullLoader);
			}
			// Opret en fullLoader til det billede, der skal vises
			fullLoader=new Loader();
			//"e.target.name" er  "thumbLoader.name" fra LOADTHUMBS
			var imgUrl=new URLRequest(e.target.name);
			fullLoader.load(imgUrl);
			fullLoader.x=160;
			fullLoader.y=20;
			addChild(fullLoader);
		}

//Niveau A
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import fl.transitions.Tween;
	import fl.transitions.easing.*;
//Niveau B
		public var imageText:TextField=new TextField();
		public var fadeTween:Tween;
//Niveau C
			// Sæt tekstboksens bredde
			imageText.autoSize=TextFieldAutoSize.LEFT;
			// Opret den tekstboks, som skal indeholde billedtekst
			addChild(imageText);
			// Kan starte med at vise en instruktion til bruger
			imageText.text=" Klik på en af billederne for at se et stort";
//Niveau D, indenfor SHOWFULL funktionen - nederst 
			// Placer tekstboksen lige over billedkanten
			imageText.x=fullLoader.x;
			imageText.y=fullLoader.y-20;		
			// Find den billedtekst, der hører til 
			for (var j:int=0; j<xmlList.length(); j++) {
				// Samlign thumbLoaders navn med alle xml-listens "full" atributter
				// "e.target.name" er "imageLoader.name" fra LOADTHUMBS
				if (xmlList[j].attribute("full")==e.target.name) {
					// Indholdet fra nummer "j" på xmlList er tekst indpakket i tags			
					// Overfør denne tekst til tekstboksen
					imageText.text=xmlList[j];
					// Igangsæt den importerede Tween class med ønskede indstillinger
					fadeTween=new Tween(fullLoader,"alpha",None.easeNone,0,1,1,true);
				}
			}

//A
import fl.motion.Color;
import flash.geom.ColorTransform;
//D
function tintColor(mc:MovieClip, colorNum:Number, alphaSet:Number) {
   var cTint:Color = new Color();
   cTint.setTint(colorNum, alphaSet);
   mc.transform.colorTransform = cTint;
}
//C/D
// Kald funktionen med værdier for dens 3 parametre: 
// pågældende movieclip, den ønskede farve, mægde af alpha
tintColor(mc2, 0xFF00FF, .5);

//////////////////////////
//Scenens størrelser - NB: angiv værdier i tal
//hvis filmen skal kunne loades ind i en andenswf.
var SW:int=stage.stageWidth;
var SH:int=stage.stageHeight;
//lokale faktiske mål, som nye mål kan beregnes udfra
var aW:Number=areas.width;
var aH:Number=areas.height;
/////////////////////////////
// Antal trin før målet nås (ease in)
var steps:int=12;
// zoom faktorer i forhold til scenestørrelse
var zFactorBig:int=3;
var zFactorSmall:int=1;
////////////////////////////
//Den skalering (stor lille) areas skal vises med nu
var zFactor:int=zFactorBig;
//areas indledende skalering
var targW:Number;
var targH:Number;
// Det mål, som areas haster imod lige nu
var targX:Number=areas.x;
var targY:Number=areas.y;
//////////////////

menu.buttonMode=true;
menu.addEventListener(MouseEvent.MOUSE_DOWN, drag);
menu.addEventListener(MouseEvent.MOUSE_UP, drop);
menu.a1but.buttonMode=true;
menu.a1but.addEventListener(MouseEvent.CLICK, setTarget);
menu.a2but.buttonMode=true;
menu.a2but.addEventListener(MouseEvent.CLICK, setTarget);
areas.area1.buttonMode=true;
areas.area1.addEventListener(MouseEvent.CLICK, setTarget);
areas.area2.buttonMode=true;
areas.area2.addEventListener(MouseEvent.CLICK, setTarget);
menu.zoombut.buttonMode=true;
menu.zoombut.addEventListener(MouseEvent.CLICK, setTarget);
areas.bund.addEventListener(MouseEvent.CLICK, setTarget);

//////////////////////////
function drag(e:MouseEvent):void {
	e.target.startDrag();
}
function drop(e:MouseEvent):void {
	e.target.stopDrag();
}
///////////////////////////
function setTarget(e:MouseEvent) {
	// op- og ned-zomning (bund og den røde knap)
	if (e.target.name=="zoombut"||e.target.name=="bund") {
		// hvis målet var lille, så sæt det til stort - ellers omvendt!
		if (zFactor==zFactorSmall) {
			zFactor=zFactorBig;
			//areas koordinater, musens klik, skaleret op og centreret
			targX=(-mouseX*zFactorBig)+(SW/2);
			targY=(-mouseY*zFactorBig)+(SH/2);
		} else {
			zFactor=zFactorSmall;
			targX=0;
			targY=0;
		}
	}
	//forskellen mellem areas medfødte mål og det skalerede mål
	//bruges til at finde area1's og area2's præcise koordinater 
	var adifX:Number=((SW*zFactorBig)/aW);
	var adifY:Number=((SH*zFactorBig)/aH);
	if (e.target==menu.a1but||e.target==areas.area1) {
		zFactor=zFactorBig;
		targX=-(areas.area1.x*adifX)+(SW/2);
		targY=-(areas.area1.y*adifY)+(SH/2);
	}
	if (e.target.name=="a2but"||e.target.name=="area2") {
		zFactor=zFactorBig;
		targX=(-areas.area2.x*adifX)+(SW/2);
		targY=(-areas.area2.y*adifY)+(SH/2);
	}
	targW=SW*zFactor;
	targH=SH*zFactor;
	areas.addEventListener(Event.ENTER_FRAME, GETGOING);
}
//////////////////
function GETGOING(e:Event):void {
	areas.x += (targX-areas.x)/steps;
	areas.y += (targY-areas.y)/steps;
	areas.width += (targW-areas.width)/steps;
	areas.height += (targH-areas.height)/steps;
	//Hvis den næsten er i mål, så siger vi den er hjemme og slukker motoren!
	if (Math.abs(areas.x - targX) < 1 && Math.abs(areas.y-targY)<1&&Math.abs(targW-areas.width) < 1 && Math.abs(targH-areas.height) < 1) {
		areas.x=targX;
		areas.y=targY;
		areas.width=targW;
		areas.height=targH;
		areas.removeEventListener(Event.ENTER_FRAME, GETGOING);
	}
}